The FabLab offers a space where students can produce their own designs or just print stuff downloaded from thingiverse. The place is still in a build-up phase but have a look at all the good(ness/ies) it has already.

2 Bits from Bytes RepMan's

These can be purchased as a kit from BitsFromBytes

RepMan

Funky Fan

Mr. MakerBot aka Cupcake

Not entirely sure but my guess is the Cupcake was gutted from it’s electronics to be used to power the lasercut Mendel below.

The lasercut mendel is a thesis project by Frederic Decru aka the Lasercut-Mendel-Guy. He can be seen in this video and the model can be obtained from thingiverse by going here

Lasercut Mendel

Lasercut Mendel looking all Acrylicalicaly'ish

Lasercut Mendel's good side

I hope to get me a lasercut mendel somewhere in the near future.

Batist and a printed Mendel

Batist started the FabLab and is seen constructing a printed version of the Mendel RepRap.

I hope to, someday soon, reserve a slot on one of the 3D printers in the FabLab and print the case I’m designing for my IGEPv2 board.

It’s a beagleboard clone with the exception that this version comes packed with a RJ45 10/100Mb ethernet connection, bluetooth and  802.11b/g wifi. Oh and the price is about the same as a beagleboard (it’s actually cheaper then a BB when you opt for the non-wifi version).

Here are some specs from the ISEE website:

• TI OMAP35x pin compatible family multicore processor
• ARM CORTEX A8 core
• DSP TMS320C64x+ core
• POWERVR SGX 530 core (OpenGL® ES 2.0, OpenGL® ES 1.0 , OpenVG)
• IVA2.2 (Video Hardware Accelerators)
• DDR RAM plus NAND Flash Package on Package (PoP) memories (on OMAP chip)
• Linux BSP available (Board Support Package)
• Ethernet 10/100 Mb BaseT.
• Wifi IEEE 802.11b/g + Bluetooth 2.0 (Integrated antenna).
• Compatibility with a huge collection of USB peripherals including hubs, keyboards, mice, web cameras, and much more.
• MicroSD connector.
• DVI-D for connecting digital computer monitors.
• Stereo audio in and out for a microphone and headphones or speakers.
• Expansion connector with I/O, SPI, UART…
• Expansion connector with access LCD lines.
• Wall plug 5 Vdc or JST input.
• RS-485 Transceiver.
• 2 ADC : 1 and 3 MSP/s.
• Temperature Range: -40 to +80º C.
• EMI and EMC precertificate. CE compliant.

Did I mention it’s really small? As in ‘Djeez that sure is really small!’.

I’ve mounted the IGEPv2 board on a lego structure to make (dis)connecting cables a bit easier and to prevent static discharges of causing any mayhem. The mounting holes in the pcb are spaced equal to the offset in the lego beams so there was no need for drilling or hotglue.

Of course this is just fine for use on your desktop but rather useless when trying to protect your precious board from the (or atleast some) elements. So I wanted an affordable case. ISEE sells a housing for 15EUR, but as I forgot to order one when ordering the board, the price of shipping about doubles that figure, crossing it from the list of options. Specialcomp has a housing for $29 making it even less of an option.

Borglabs has a cool tutorial on how to hack a $5 soap box to make an enclosure. This is definitely the best value for money you’ll get.

I liked the specialcomp acrylic housing but disliked the pricetag. So I deciced to make my own. I fired up sketchup and looked for a model of the IGEP board in the store, none were found. So as any sensible human being would do, instead of just using a box with some holes as a mockup, I had to draw the thing myself.

Some renders of the 3D-model:

Most of the parts were just downloaded from the store and I don’t take any credit for them. I just wanted a 3D model where connector positions were accurate enough to design a case.

The model is on a 1/1 scale and the .kmz file can be downloaded here : igepv2_revB_board

I’m getting some errors uploading the model to the sketchup store but I’ll post a link when it’s done.

Only thing left to do now is design a case. And when I have a few spare moments, I will.

So watch out for a future post with a 3D model of a case and probably some instructions on how to reproduce and assemble one yourself.

Notes :

• for this setup the connections are made on the ethernet shield instead of directly on the arduino. Since Fritzing misses a library with external shield I used the arduino, the pinout stays the same either way.
• check the DS18B20 datasheet for the specifications on hooking up the sensor in parasite or powered mode

Schematics :

The arduino reads the sensors every 10 seconds and passes the data to a php script on your website; which then stores the data in a text file. A second script generates a line chart of the collected data.

22 hours of temperature data

I started from Cyberspice’s code and changed the arduino code to make use of the DB18S20 and the ethernet shield.

A variable was added to the upload php script in order to store the light intensity in addition to the temperature.

The graphing script was altered to also display the minimum temperature, the maximum temperature, the current temperature and the average temperature. A raster was added for a better interpretation of the plotted data and a green line is showing the average temperature  troughout the chart.

You need to alter your ip, domain and path as I explained in the post Arduino Wireless motion detector so I won’t go into those details here.

The arduino sketch :

#include <OneWire.h>
#include <string.h>
#include <Ethernet.h>

int count = 0;
OneWire ds(8);
int HighByte, LowByte, TReading, SignBit, Tc_100, Tf_100, Whole, Fract;
int Tcount = 1;
int W[6];
int F[6];
int photocellPin = 0;     // the cell and 10K pulldown are connected to a0
int light;     // the analog reading from the sensor divider

byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
byte ip[] = {
  192, 168, 1, 36};
byte server[] = { 77, 222, 78, 32};
// String buffer
char buffer[256];

Client client(server, 80);

void setup()
{
  Ethernet.begin(mac, ip);
  Serial.begin(9600);

  delay(1000);

  // Serial.println("connecting...");

}

void loop()
{
  byte i;
  byte present = 0;
  byte data[12];
  byte addr[8];

  if ( !ds.search(addr)) {
    ds.reset_search();
    return;
  }

  ds.reset();
  ds.select(addr);
  ds.write(0x44,1);         // start conversion, with parasite power on at the end

  delay(1000);            

  present = ds.reset();
  ds.select(addr);
  ds.write(0xBE);         // Read Scratchpad

  light = analogRead(photocellPin);
  Serial.print("light intensity = ");
  Serial.print(light);
  Serial.print("\n");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
  }

  LowByte = data[0];
  HighByte = data[1];
  TReading = (HighByte << 8) + LowByte;
  SignBit = TReading & 0x8000;  // test most sig bit
  if (SignBit) // negative
  {
    TReading = (TReading ^ 0xffff) + 1; // 2's comp
  }
  Tc_100 = (6 * TReading) + TReading / 4;    // multiply by (100 * 0.0625) or 6.25

  Whole = Tc_100 / 100;  // separate off the whole and fractional portions
  Fract = Tc_100 % 100;

  if (SignBit) // If its negative
  {
    Serial.print("-");
  }
  Serial.print(Whole);
  Serial.print(".");
  if (Fract < 10)
  {
    Serial.print("0");
  }
  Serial.print(Fract);
  Serial.print(" C\n");

  if (client.connect()) {
    Serial.println("connected");
 sprintf(buffer, "HEAD /path/to/script/newtemp.php?count=%d&temp=%d.%d&light=%d HTTP/1.1", Tcount, Whole, Fract, photocell);
 client.println(buffer);
 client.println("Host: yourdomain.com");
 client.println("Connection: close");
 client.println();
 client.stop();
 Tcount++;
 }
 else {
 Serial.println("connection failed");
 }
 delay(60000);  // wait 1 minute before sending new data
}

The upload script  ‘newtemp.php’ :

<?php

if ($_SERVER['REQUEST_METHOD'] == 'HEAD') {

	$fields = explode("&", $_SERVER['QUERY_STRING']);
	$values = array();

	foreach ($fields as $field) {
		$keyval = explode("=", $field);
		$values[$keyval[0]] = $keyval[1];
	}

	$file = fopen('./tempdata.txt','a+');
	if ($file) {
		fwrite($file, time() . ':' . $values['count'] . ':' . $values['temp'] . ':' . $values['light']);
		fwrite($file, "\n");
		fclose($file);
	}
}

?>

The graphing script ‘tempgraph.php’ :

<?php

define('WIDTH', 1000);
define('HEIGHT', 520);
define('FONT', 1);
 define('FONT2',2);

// Get the temperature data
$data = array();
$file = fopen("./tempdata.txt","r");
if ($file) {
	while (!feof($file)) {
		$line = trim(fgets($file));
		if (strlen($line)) {
			$fields = explode(":", $line);
			$keyval = array();
			$keyval['time']        = $fields[0];
			$keyval['count']       = $fields[1];
			$keyval['temperature'] = $fields[2];
			$keyval['light'] 	   = $fields[3];
			$data[] = $keyval;
		}
	}

	fclose($file);
}

// Get the number of data points
$datapoints = count($data);

// Lines are chronological
$mintime = $data[0]['time'];
$maxtime = $data[$datapoints - 1]['time'];

// Temperatures need to be processed.
$mintemp = $data[0]['temperature'];
$maxtemp = $data[0]['temperature'];

foreach ($data as $datapoint) {
	$mintemp = $mintemp < $datapoint['temperature'] ?
	           $mintemp : $datapoint['temperature'];
	$maxtemp = $maxtemp > $datapoint['temperature'] ?
	           $maxtemp : $datapoint['temperature'];
	$avgtemp += $datapoint['temperature'];
	$curtemp = $datapoint['temperature'];
}
 $avgtemp = round(($avgtemp / $datapoints),2);

// Get the axis dimensions.  Round up and down to the nearest
// degree C and hour.
$lowtime  = intval($mintime / 3600) * 3600;
$hightime = (intval($maxtime / 3600) + 1) * 3600;
$difftime = $hightime - $lowtime;

$lowtemp  = intval($mintemp);
$hightemp = intval($maxtemp) + 1;
$difftemp = $hightemp - $lowtemp;

// Create the image
$image = imagecreate(WIDTH, HEIGHT);
if ($image) {
	$background = imagecolorallocate($image, 255, 255, 255);
	$black      = imagecolorallocate($image, 0, 0, 0);
	$red        = imagecolorallocate($image, 255, 0, 0);
	$blue       = imagecolorallocate($image, 0, 0, 255);
	$green		= imagecolorallocate($image, 0, 204, 5);
	$grey		= imagecolorallocate($image, 210,210,210);

	// Draw the axes
	imageline($image, 20, 20, 20, 485, $black);
	imageline($image, 15, 480, 980, 480, $black);
	imageline($image, 15, 20, 20, 20, $black);
	imageline($image, 980, 480, 980, 485, $black);

	// Draw top horizontal line
	imageline($image, 20, 20, 980, 20, $grey);

	// Draw right most vertical line
	imageline($image, 980, 20, 980, 479, $grey);

	for ($i = 3600; $i < $difftime; $i += 3600) {
		$x = 20 + (($i * 960) / $difftime);
		// Draw ticks on horizontal axis
		imageline($image, $x, 480, $x, 483, $black);
		// Draw horizontal guides
		imageline($image, $x, 479, $x, 20, $grey);
	}
	$temp = intval($lowtemp);
	for ($i = 1; $i < $difftemp; $i++) {
	    $y = 480 - (($i * 460) / $difftemp);
		// Draw ticks on vertical axis
		imageline($image, 17, $y, 20, $y, $black);

		// Draw vertical guides
		imageline($image, 21, $y, 980, $y, $grey);
		$temp = intval($temp) + 1;
		$ytemp = intval($y) - 5;
		//if($temp % 2 == 0){
			imagestring($image, FONT, 0, $ytemp, $temp . 'C', $black);
		//}
	}

	// Draw the labels
	imagestring($image, FONT, 8, 490, date("H:i", $lowtime), $black);
	imagestring($image, FONT, 970, 490, date("H:i", $hightime), $black);
	imagestring($image, FONT, 0, 475, $lowtemp . 'C', $black);
	imagestring($image, FONT, 0, 15, $hightemp . 'C', $black);

	// Draw min, max and avg
	imagestring($image, FONT2, 700, 430, "Cur. temp : " . $curtemp . " °C",$black);
	imagestring($image, FONT2, 700, 450, "Avg. temp : " . $avgtemp . " °C",$green);
	imagestring($image, FONT2, 850, 430, "Min. temp : " . $mintemp . " °C",$blue);
	imagestring($image, FONT2, 850, 450, "Max. temp : " . $maxtemp . " °C",$red);

	// Draw avg line

	$avgtemp = 480 - ((($avgtemp - $lowtemp) * 460) / $difftemp);
	imageline($image,20, $avgtemp, 980, $avgtemp, $green);

	// Draw the temperature points

	// Position of the first point
	$prevx = (($data[0]['time'] - $lowtime) * 960) / $difftime;
	$prevy = (($data[0]['temperature'] - $lowtemp) * 460) / $difftemp;

	// Draw line from previous point to current point
	for ($i = 1; $i < $datapoints; $i++) {
		$x = (($data[$i]['time'] - $lowtime) * 960) / $difftime;
		$y = (($data[$i]['temperature'] - $lowtemp) * 460) / $difftemp;
		imageline($image, $prevx + 20, 480 - $prevy, $x + 20, 480 - $y, $red);
		$prevx = $x;
		$prevy = $y;
	}

	// Finally time and date stamp
	$generated = 'Generated: ' . date("r");
	imagestring($image,
	            FONT,
	            WIDTH - 15 - (imagefontwidth(FONT) * strlen($generated)),
	            HEIGHT - 15,
	            $generated,
	            $blue);

	// Output the image
	header('Content-Type: image/png');
	imagepng($image);

	// Destroy it
	imagedestroy($image);
}

?>

I will soon post some improvements on the scripts :

• averaging 6 readings ( 1 minute ) to 1 datapoint to get rid of the noise
• let the script fill one text file for each day, so you can look at a history over several days
• split up data into different charts
• last but not least, trying to add the S65 in the game : showing the current sensor readings or a graph

Please leave a comment or send me a link to show your arduino projects!

Back to homepage

Be sure to check out the other videos …

MAKE presents : the LED

MAKE presents : the Resistor

MAKE presents : the Capacitator

MAKE presents : the Transistor

MAKE presents : the Diode

MAKE presents : the Integrated Circuit (IC)

Rossum made a an awesome device with just an 8-bit Atmel AVR ATmega644 processor and a cheap touchscreen LCD.

S65 displaying random text

It consists of :

- a Siemens S65 16-bit color screen with 172×136 pixels

- a rotary switch (left-right-press)

- a micro-SD slot (bottom)

S65 bottom

You can visit the project page to check progress made to the libraries and hardware.The most recent library is v0.08 . It’s actually more like 3 libraries:  ‘S65Display’, ‘RotaryEncoder’ and ‘SDCard’.

You can check the documentation that comes with the libraries to view this baby shields’ possibilities. So far this shield seems to be a bargain (compaired to other display-shields out there) selling at only €35 that’s equal to $51.36600 or 4640.5276 Japanese  Yen or 149.793533 Polish Zloty or your virginity if you’re misfortuned enough to live in one of those countries, anyhow.

It has some pretty long headers which make it easy to mount on top of the tallest board you own.

S65 mating with Duemilanove

I don’t have a microSD card at hand so I can’t test the SDCard library for now. Which sucks since you can load images stored on the microSD and display them on the screen. You can also use the images for buttons, icons, etc in your sketches… how cool is that?

Here’s an example of the awsome S65-Shield in action on an Arduino Duemilanove with 328 Atmel running a Game of Life sketch. I am not the author of this code, he gave me the code for testing and learning purposes. I just added the rotary delay. Maybe he’ll give his consent later so I can post the code online. Foo Joku gave his consent, the code is posted after the video.

The display and colors look much better in real life, this video was shot with an old digital camera in bad light conditions.

GOL code:
#include <S65Display.h>
#include <RotaryEncoder.h>

#define GRID_X 28
#define GRID_Y 20

#define GRID_X_OFFSET 4
#define GRID_Y_OFFSET 6

#define COLOUR_SWITCH_INTERVAL 30

#define MAX_GENERATIONS 250

S65Display lcd;
RotaryEncoder encoder;

uint8_t grid[2][GRID_X][GRID_Y];
uint8_t current_grid = 0;

uint8_t generations = 0;
uint8_t r = 255,g = 0, b = 0;

// Encoder must be serviced regularly.
ISR(TIMER2_OVF_vect)
{
 TCNT2 -= 250; //1000 Hz
 encoder.service();
}

void setup()
{
 lcd.init(4);
 encoder.init();
 // More encoder stuff
 //init Timer2
 TCCR2B  = (1<<CS22); //clk=F_CPU/64
 TCNT2   = 0x00;
 TIMSK2 |= (1<<TOIE2); //enable overflow interupt

 sei();
 initGrid();
 lcd.clear(0);
 drawGrid();
}

void loop()
{
 //delay(50);
 checkEncoder();
 runGrid();
 drawGrid();
 generations++;
 if (generations > MAX_GENERATIONS || cmpGrid()) {
 generations = 0;
 initGrid();
 }
 cycleColour();
 cycleColour();
 cycleColour();
}

int cmpGrid()
{
 int i, j;
 for (i=0; i < GRID_Y; i++) {
 for (j=0; j < GRID_X; j++) {
 if (grid[0][i][j] != grid[1][i][j]) { return 0; }
 }
 }
 return 1;
}

void initGrid()
{
 int i, j;
 int t;
 lcd.clear(0);
 current_grid = 0;
 for (i = 0; i < GRID_X; i++) {
 for (j = 0; j < GRID_Y; j++) {

 if ((uint8_t)random(255) % 3 == 0) {
 grid[0][i][j] = 1;
 } else {
 grid[0][i][j] = 0;
 }
 }
 }
}

void runGrid()
{
 uint8_t x, y;
 int count;
 char string[2] = {0,0};
 uint8_t value = 0;
 uint8_t new_grid;

 new_grid = 1 - current_grid;
 for (y = 0; y < GRID_Y; y++) {
 for (x = 0; x < GRID_X; x++) {
 count = count_neighbours(x, y);
 string[0] = count+48;
 if (count < 2 || count > 3) { value = 0; }
 else if (count == 3) { value = 3; }
 else { value = grid[current_grid][x][y]; }
 grid[new_grid][x][y] = value;
 }
 }
 current_grid = new_grid;
}

int count_neighbours(int x, int y)
{
 int i, j;
 int sx;
 int result = 0;

 x--;
 y--;
 for (i = 0; i < 3; i++) {
 if (y < 0 || y > (GRID_Y - 1)) { continue; }
 for (j = 0; j < 3; j++) {
 if (x < 0 || x > (GRID_X - 1)) { continue; }
 if (i==1 && j == 1) { x++; continue; } // skip centre
 if (grid[current_grid][x][y]) { result++; }
 x++;
 }
 y++;
 x -= 3;
 }
 return result;
}

void drawGrid()
{
 uint8_t  x,  y;
 uint8_t cx, cy;
 uint8_t grid_next_colour = 0;
 cx = GRID_X_OFFSET;
 cy = GRID_Y_OFFSET;
 for (y = 0; y < GRID_Y; y++) {
 cx = GRID_X_OFFSET;
 for (x = 0; x < GRID_X; x++) {
 if (grid[1-current_grid][x][y] != grid[current_grid][x][y]) {
 if(grid[current_grid][x][y]) {
 lcd.drawRect(cx+1, cy+1, cx+5, cy+5, RGB(r,g,b));
 } else {
 lcd.drawRect(cx, cy, cx+6, cy+6, 0);
 }
 }
 cx += 6;
 }
 cy += 6;
 }
}

inline void cycleColour()
{
 if (!b && r)  { r-=5; g+=5; }
 else if (g) { g-=5; b+=5; }
 else if (b) { b-=5; r+=5; }
}

void checkEncoder(void)
{
 int8_t press;
 press = encoder.sw();

 if ( !press ) { return; }

 if (SW_PRESSED == press || SW_PRESSEDLONG == press) {
 initGrid();
 lcd.clear(0);
 }
}

 Back to homepage

When building a project it’s better to test and debug each part on its own instead of trying to debug a much larger system. So we’ll start by attaching an ethernet shield and get it to talk to a webpage. Once that is up and running we’ll connect the second arduino and rf.

Note: For this part you’ll need a webhosting account with a company who provides access to PHP on it’s accounts. Or you’ll need to run a local webserver. Contact your webhost to verify if your account has PHP access enabled.

Arduino Ethernet Shield

First we’ll create a script named ‘time.php’ which will print out the date and time when we visit www.yourdomain.com/time.php . Open the file and paste the following code:

<?php
// Prints something like: Sunday 25th of October 2009 07:12:46 PM
echo date('l jS \of F Y h:i:s A');
?>

Now close, save and upload time.php to your domain. If you put the script in the www or public_html folder it will be accesible from www.yourdomain/time.php if you’ve placed it inside another folder make sure to use www.yourdomain.com/folder/time.php in the next part.

Before we continue, open a webbrowser and go to www.yourdomain/time.php or wherever you placed the script and make sure it shows the date and time.

When the script is working, start the arduino IDE , create a new sketch and copy paste the code below

#include <Ethernet.h>

byte mac[] = {   0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
byte ip[] = {   xxx, xxx, xxx, xxx};
byte server[] = { yyy, yyy, yyy, yyy};

Client client(server, 80);

void setup()
{
  pinMode(switchPin, INPUT);
  Ethernet.begin(mac, ip);
  Serial.begin(9600);

  delay(1000);

  Serial.println("connecting...");

  if (client.connect()) {
    Serial.println("connected");
    client.print("GET http://www.yourdomain.com/folder/time.php HTTP/1.0\n");
    client.print("Host: www.yourdomain.com\n\n");
    client.println();
  }
  else {
    Serial.println("connection failed");
  }
}

void loop()
{
  if (client.available()) {
    char c = client.read();
    Serial.print(c);
  }

  if (!client.connected()) {
    Serial.println();
    Serial.println("disconnecting.");
    client.stop();
    for(;;)
      ;
  }
}

byte ip[] = { xxx, xxx, xxx, xxx};

Make sure to change the xxx, xxx, xxx, xxx with your settings, where xxx, xxx, xxx, xxx should be an available ip in the range of your network. Check your router for the range of ip-adresses in your network.

in my case the above line would read :

byte ip[] = { 192, 168, 1, 36};

Next is the ip address of the server you wish to connect to. If your webhost does not provide you with a unique ip dedicated to your domain you should try using google’s ip. To check if your domain is asigned a unique ip ( your domain is the only one hosted on that ip ) open a command prompt and ping your domain with ‘ping www.yourdomain.com’.  On the next line the ip adress associated with your domain should show up on windows in the form of ‘Ping statistics for domain xxx.xxx.xxx.xxx’. Now open a browser and type in xxx.xxx.xxx.xxx instead of www.yourdomain.com. If you are seeing your domain, you have a unique ip assigned to your domain. If not, ping www.google.com and use the ip adress returned for the yyy.yyy.yyy.yyy below.

byte server[] = { yyy, yyy, yyy, yyy};

So the server ip becomes :

byte server[] = { 74, 125, 67, 100};

These settings should get you up and running. The only thing left to do is change these lines to match your domain and the url of the time.php script :

client.print("GET http://www.yourdomain.com/folder/time.php HTTP/1.0\n");
client.print("Host: www.yourdomain.com\n\n");

Now upload the code to the arduino and open the serial monitor.
If all went well the monitor should show something similar:

Serial Monitor

As you can see second to last line displays the correct date and time.

Check part 3 where I show you how to put it all together to create a weblogging wireless motion detector.

Back to homepage

The two rf-boards used in this setup were discussed earlier in this post.

The left arduino has a sensorshield with a PIR-sensor and a rf-transmitter connected to it. When the PIR-sensor detects changes in IR-radition in it’s field of view, it triggers the rf-transmitter and a red led.

The right arduino just has a rf-receiver and a green led connected to it. When the right arduino receives a radio signal the green led turns on.

Code for the transmitting arduino:

int ledPin = 12;                 // pin
int pirPin = 4;                  // pin for PIR-sensor
int RFoutPin = 7;                // pin for RF transmitter
int value = 0;                   // used to store data from PIR-sensor

void setup() {
pinMode(RFoutPin, OUTPUT);       // declare RF-transmitter as output
  pinMode(ledPin, OUTPUT);       // declare led as output
pinMode(pirPin, INPUT);          // declare PIR-sensor as input
}

void loop() {
value = digitalRead(pirPin);     // read PIR-sensor
if (HIGH == value) {             // transmit HIGH signal
digitalWrite(RFoutPin, HIGH);
digitalWrite(ledPin, HIGH);
}
else {                           // transmit LOW signal
    digitalWrite(RFoutPin, LOW);
    digitalWrite(ledPin, LOW);
 }

}

Code for the receiving side:

int ledPin = 11;                  // pin for the LED
int RFinPin = 7;                  // pin for the RF receiver
int val = 0;                      // variable for reading the pin status
void setup() {
pinMode(ledPin, OUTPUT);          // declare LED as output
pinMode(RFinPin, INPUT);          // declare RF receiver as input
}
void loop(){
 val = digitalRead(RFinPin);      // read input value
 if (val == HIGH) {               // check if the input is HIGH
    digitalWrite(ledPin, HIGH);   // turn LED ON
 } else {
  digitalWrite(ledPin, LOW);      // turn LED OFF
  }
}

Ok, maybe this example was a bit too easy.

Check part 2 to learn how to connect arduino to a network and send/receive data to/from a webpage using the ethernet shield discussed here.

Back to homepage

This is the rest of the parts I received:

Arduino Sensor Shield

The Arduino Sensor Shield is a handy extension for attaching sensors and servo’s using standard cables

The shields provides you with:

• 6 analog connectors ( 5 on the left and one on the bottom )
• 13 digital IO headers (4 x 4 3-pin headers )
• 6 analog IO headers ( 6 3-pin headers )
• Communication port ( I2C or UART, connector on the right)

Sensor Shield with PIR-sensor attached

A PIR or Passive Infrared Sensor is a device that measures infrared light radiating from any objects in its field of view. These sensors are often used in backyard or driveway motion detectors.   Bassicaly they measure the amount of IR radiated by objects around it and detect sudden fluctuations  i.e. caused by a person walking into a sensors’ field of view.

I love the sensor shield for prototyping purposes, it will certainly lower the number of connections to your breadboard.

All these parts were bought on ebay, search for ‘arduino sensor shield’ by clicking  here

RF receiver-transmitter pair

A RadioFrequency receiver-transmitter pair with 4-channels, 1 connector for each channel. The one on the left is the receiver, it also came with an antenna, like the one you see on the right, but it wasn’t soldered on.

The green transmitter and receiverboards have male headers and plug into the female headers mounted on the red extender boards. I have played around with them and can say that they work. I still need to check the maximum range these things will go. These were tested to be working at 4 meters appart with a wooden door and a drywall in between.

In a next post I’ll demonstrate an arduino motion-sensor-over-rf  to a webserver running php

pir-sensor  >>  arduino >>  rf-transmitter   . . .  _ _ _ . . .    rf-receiver  >>  arduino >>  ethernetshield >>  php

Back to homepage

This is the first of a few items I recentely bought from ebay: An arduino EthernetShield based on the WIZ5100 ethernet controller.

Arduino Ethernet Shield based on the WIZ5100 ethernet controller

Ever since I started thinkering with Arduino I wanted a way to connect it to a network.  So befor I got this shield I started messing around with a fonera router by connecting the rx-tx lines of the arduino to the tx-rx connections of a fonera 2100 router.  However to be able to acces the fonera via serial you need to reflash it with a third-party image (open-wrt, dd-wrt,…) . The image needs to include the tty or stty command, which enables you to set the serial communication speed of the router to a baudspeed the arduino can handle.

Arduino to Fonera Serial Communication and Duvel beer

I’ll post a guide later containing information on how to connect to a fonera router and control it wireless. The major downside of this way of connecting to a network is the usage of the RX-TX lines on the arduino board. Making it harder to debug and thus making it harder to whip something up real quick.

To be completely honnest, she wasn’t my first… .  Some time ago in a moment of weakness I was in the believe I had struck upon a genuine bargain : a (very) cheap arduino ethernet shield. As I was later to realize, the price was about right. The problem with this shield is that is uses the Microchip’s ENC28J60 SPI based ethernet controller.

"Arduino Ethernet Shield V1.1" using ENC28J60 SPI controller.

I don’t mean to bash the ENC28J60 based shield, but it shouldn’t be branded  “Arduino Ethernet Shield v1.1″ as it uses a different chip and design as stated in the reference design on the arduino website.  Because of the different chip the library you need to include differs from the arduino ethernet library. Since the library is different the code you need to write is different and in this case it could use some more abastraction.

Note : I did not buy my shield from nuelectronics but from a seller on ebay. Both shields however use the ENC28j60 chip and both are branded Arduino Ethernet Shield V1.x so my guess is in one way or the other they originated from the same place/drawingboard.

To better explain what I’m talkin about I’ll show two example programs. The first example is for the ENC28j60 based shield, the second example is for the WIZ5100 based shield using the official ethernet library.

The first code example is included in the etherShield library provided by nuelectronics

#include "etherShield.h"

// please modify the following lines. mac and ip have to be unique
// in your local area network. You can not have the same numbers in
// two devices:
static uint8_t mymac[6] = {0x54,0x55,0x58,0x10,0x00,0x24};
static uint8_t myip[4] = {192,168,1,88};
static uint16_t my_port = 1200;     // client port

// client_ip - modify it when you have multiple client on the network
// for server to distinguish each ethershield client
static char client_ip[] = "192.168.1.88";

// server settings - modify the service ip to your own server
static uint8_t dest_ip[4]={192,168,1,4};
static uint8_t dest_mac[6];

enum CLIENT_STATE
{
   IDLE, ARP_SENT, ARP_REPLY, SYNC_SENT
 };

static CLIENT_STATE client_state;

static uint8_t client_data_ready;

static uint8_t syn_ack_timeout = 0;

#define BUFFER_SIZE 500
static uint8_t buf[BUFFER_SIZE+1];

char sensorData[10];

EtherShield es=EtherShield();

// prepare the webpage by writing the data to the tcp send buffer
uint16_t print_webpage(uint8_t *buf);
int8_t analyse_cmd(char *str);
// get current temperature
#define TEMP_PIN  3
void getCurrentTemp( char *temperature);
void client_process(void);

void setup(){

   /*initialize enc28j60*/
	 es.ES_enc28j60Init(mymac);
   es.ES_enc28j60clkout(2); // change clkout from 6.25MHz to 12.5MHz
   delay(10);

	/* Magjack leds configuration, see enc28j60 datasheet, page 11 */
	// LEDA=greed LEDB=yellow
	//
	// 0x880 is PHLCON LEDB=on, LEDA=on
	// enc28j60PhyWrite(PHLCON,0b0000 1000 1000 00 00);
	es.ES_enc28j60PhyWrite(PHLCON,0x880);
	delay(500);
	//
	// 0x990 is PHLCON LEDB=off, LEDA=off
	// enc28j60PhyWrite(PHLCON,0b0000 1001 1001 00 00);
	es.ES_enc28j60PhyWrite(PHLCON,0x990);
	delay(500);
	//
	// 0x880 is PHLCON LEDB=on, LEDA=on
	// enc28j60PhyWrite(PHLCON,0b0000 1000 1000 00 00);
	es.ES_enc28j60PhyWrite(PHLCON,0x880);
	delay(500);
	//
	// 0x990 is PHLCON LEDB=off, LEDA=off
	// enc28j60PhyWrite(PHLCON,0b0000 1001 1001 00 00);
	es.ES_enc28j60PhyWrite(PHLCON,0x990);
	delay(500);
	//
  // 0x476 is PHLCON LEDA=links status, LEDB=receive/transmit
  // enc28j60PhyWrite(PHLCON,0b0000 0100 0111 01 10);
  es.ES_enc28j60PhyWrite(PHLCON,0x476);
	delay(100);

  //init the ethernet/ip layer:
  es.ES_init_ip_arp_udp_tcp(mymac,myip,80);

  // intialize varible;
  syn_ack_timeout =0;
  client_data_ready = 0;
  client_state = IDLE;
  // initialize DS18B20 datapin
    digitalWrite(TEMP_PIN, LOW);
    pinMode(TEMP_PIN, INPUT);      // sets the digital pin as input (logic 1)

}

void loop(){

        if(client_data_ready==0){
          delay(60000UL);             // delay 60s
          getCurrentTemp(sensorData);
          client_data_ready = 1;
         }
	client_process();

}

uint16_t gen_client_request(uint8_t *buf )
{
	uint16_t plen;
	byte i;

	plen= es.ES_fill_tcp_data_p(buf,0, PSTR ( "GET /ethershield_log/save.php?pwd=secret&client=" ) );
        for(i=0; client_ip[i]!='\0'; i++){
            buf[TCP_DATA_P+plen]=client_ip[i];
            plen++;
        }
        plen= es.ES_fill_tcp_data_p(buf,plen, PSTR ( "&status=temperature-" ) );
        for(i=0; sensorData[i]!='\0'; i++){

                buf[TCP_DATA_P+plen]=sensorData[i];
                plen++;
        }	

	plen= es.ES_fill_tcp_data_p(buf, plen, PSTR ( " HTTP/1.0\r\n" ));
	plen= es.ES_fill_tcp_data_p(buf, plen, PSTR ( "Host: 192.168.1.4\r\n" ));
	plen= es.ES_fill_tcp_data_p(buf, plen, PSTR ( "User-Agent: AVR ethernet\r\n" ));
        plen= es.ES_fill_tcp_data_p(buf, plen, PSTR ( "Accept: text/html\r\n" ));
	plen= es.ES_fill_tcp_data_p(buf, plen, PSTR ( "Keep-Alive: 300\r\n" ));
	plen= es.ES_fill_tcp_data_p(buf, plen, PSTR ( "Connection: keep-alive\r\n\r\n" ));

	return plen;
}

//*****************************************************************************************
//
// Function : client_process
// Description : send temparature to web server, this option is disabled by default.
// YOU MUST install webserver and server script before enable this option,
// I recommented Apache webserver and PHP script.
// More detail about Apache and PHP installation please visit http://www.avrportal.com/
//
//*****************************************************************************************
void client_process ( void )
{
    uint16_t plen;
	uint8_t i;

    if (client_data_ready == 0)  return;     // nothing to send

	if(client_state == IDLE){   // initialize ARP
       es.ES_make_arp_request(buf, dest_ip);

	   client_state = ARP_SENT;
	   return;
	}

	if(client_state == ARP_SENT){

        plen = es.ES_enc28j60PacketReceive(BUFFER_SIZE, buf);

		// destination ip address was found on network
        if ( plen!=0 )
        {
            if ( es.ES_arp_packet_is_myreply_arp ( buf ) ){
                client_state = ARP_REPLY;
				syn_ack_timeout=0;
				return;
            }

		}
	        delay(10);
		syn_ack_timeout++;

		if(syn_ack_timeout== 100) {  //timeout, server ip not found
			client_state = IDLE;
			client_data_ready =0;
			syn_ack_timeout=0;
			return;
		}
    }

 // send SYN packet to initial connection
	if(client_state == ARP_REPLY){
		// save dest mac
		for(i=0; i<6; i++){
			dest_mac[i] = buf[ETH_SRC_MAC+i];
		}

        es.ES_tcp_client_send_packet (
                       buf,
                       80,
                       1200,
                       TCP_FLAG_SYN_V,                 // flag
                       1,                                              // (bool)maximum segment size
                       1,                                              // (bool)clear sequence ack number
                       0,                                              // 0=use old seq, seqack : 1=new seq,seqack no data : new seq,seqack with data
                       0,                                              // tcp data length
		      dest_mac,
		      dest_ip
                       );

		client_state = SYNC_SENT;
	}
  // get new packet
  if(client_state == SYNC_SENT){
    plen = es.ES_enc28j60PacketReceive(BUFFER_SIZE, buf);

       // no new packet incoming
    if ( plen == 0 )
    {
        return;
    }

       // check ip packet send to avr or not?
       // accept ip packet only
    if ( es.ES_eth_type_is_ip_and_my_ip(buf,plen)==0){
		return;
    }

       // check SYNACK flag, after AVR send SYN server response by send SYNACK to AVR
    if ( buf [ TCP_FLAGS_P ] == ( TCP_FLAG_SYN_V | TCP_FLAG_ACK_V ) )
    {

               // send ACK to answer SYNACK

               es.ES_tcp_client_send_packet (
                       buf,
                       80,
                       1200,
                       TCP_FLAG_ACK_V,                 // flag
                       0,                                              // (bool)maximum segment size
                       0,                                              // (bool)clear sequence ack number
                       1,                                              // 0=use old seq, seqack : 1=new seq,seqack no data : new seq,seqack with data
                       0,                                              // tcp data length
						dest_mac,
						dest_ip
                       );
               // setup http request to server
               plen = gen_client_request( buf );
               // send http request packet
               // send packet with PSHACK
               es.ES_tcp_client_send_packet (
                                       buf,
                                       80,                                             // destination port
                                       1200,                                   // source port
                                       TCP_FLAG_ACK_V | TCP_FLAG_PUSH_V,                        // flag
                                       0,                                              // (bool)maximum segment size
                                       0,                                              // (bool)clear sequence ack number
                                       0,                                              // 0=use old seq, seqack : 1=new seq,seqack no data : >1 new seq,seqack with data
                                       plen,                           // tcp data length
                                       dest_mac,
									   dest_ip
									   );
               return;
       }
       // after AVR send http request to server, server response by send data with PSHACK to AVR
       // AVR answer by send ACK and FINACK to server
       if ( buf [ TCP_FLAGS_P ] == (TCP_FLAG_ACK_V|TCP_FLAG_PUSH_V) )
       {
               plen = es.ES_tcp_get_dlength( (uint8_t*)&buf );

               // send ACK to answer PSHACK from server
               es.ES_tcp_client_send_packet (
                                       buf,
                                       80,                                             // destination port
                                       1200,                                   // source port
                                       TCP_FLAG_ACK_V,                  // flag
                                       0,                                              // (bool)maximum segment size
                                       0,                                              // (bool)clear sequence ack number
                                       plen,                                           // 0=use old seq, seqack : 1=new seq,seqack no data : >1 new seq,seqack with data
                                       0,                              // tcp data length
				      dest_mac,
				      dest_ip
               );;
               // send finack to disconnect from web server

               es.ES_tcp_client_send_packet (
                                       buf,
                                       80,                                             // destination port
                                       1200,                                   // source port
                                       TCP_FLAG_FIN_V|TCP_FLAG_ACK_V,                  // flag
                                       0,                                              // (bool)maximum segment size
                                       0,                                              // (bool)clear sequence ack number
                                       0,                                           // 0=use old seq, seqack : 1=new seq,seqack no data : >1 new seq,seqack with data
                                       0,
										dest_mac,
										dest_ip
				);

               return;

       }
       // answer FINACK from web server by send ACK to web server
       if ( buf [ TCP_FLAGS_P ] == (TCP_FLAG_ACK_V|TCP_FLAG_FIN_V) )
       {
               // send ACK with seqack = 1
               es.ES_tcp_client_send_packet(

                                       buf,
                                       80,                                             // destination port
                                       1200,                                   // source port
                                       TCP_FLAG_ACK_V,                 // flag
                                       0,                                              // (bool)maximum segment size
                                       0,                                              // (bool)clear sequence ack number
                                       1,                                              // 0=use old seq, seqack : 1=new seq,seqack no data : >1 new seq,seqack with data
                                       0,
									   dest_mac,
									   dest_ip
				);
			client_state = IDLE;		// return to IDLE state
			client_data_ready =0;		// client data sent
		}
  }
}

void OneWireReset(int Pin) // reset.  Should improve to act as a presence pulse
{
     digitalWrite(Pin, LOW);
     pinMode(Pin, OUTPUT); // bring low for 500 us
     delayMicroseconds(500);
     pinMode(Pin, INPUT);
     delayMicroseconds(500);
}

void OneWireOutByte(int Pin, byte d) // output byte d (least sig bit first).
{
   byte n;

   for(n=8; n!=0; n--)
   {
      if ((d & 0x01) == 1)  // test least sig bit
      {
         digitalWrite(Pin, LOW);
         pinMode(Pin, OUTPUT);
         delayMicroseconds(5);
         pinMode(Pin, INPUT);
         delayMicroseconds(60);
      }
      else
      {
         digitalWrite(Pin, LOW);
         pinMode(Pin, OUTPUT);
         delayMicroseconds(60);
         pinMode(Pin, INPUT);
      }

      d=d>>1; // now the next bit is in the least sig bit position.
   }

}

byte OneWireInByte(int Pin) // read byte, least sig byte first
{
    byte d, n, b;

    for (n=0; n<8; n++)
    {
        digitalWrite(Pin, LOW);
        pinMode(Pin, OUTPUT);
        delayMicroseconds(5);
        pinMode(Pin, INPUT);
        delayMicroseconds(5);
        b = digitalRead(Pin);
        delayMicroseconds(50);
        d = (d >> 1) | (b<<7); // shift d to right and insert b in most sig bit position
    }
    return(d);
}

void getCurrentTemp(char *temp)
{
  int HighByte, LowByte, TReading, Tc_100, sign, whole, fract;

  OneWireReset(TEMP_PIN);
  OneWireOutByte(TEMP_PIN, 0xcc);
  OneWireOutByte(TEMP_PIN, 0x44); // perform temperature conversion, strong pullup for one sec

  OneWireReset(TEMP_PIN);
  OneWireOutByte(TEMP_PIN, 0xcc);
  OneWireOutByte(TEMP_PIN, 0xbe);

  LowByte = OneWireInByte(TEMP_PIN);
  HighByte = OneWireInByte(TEMP_PIN);
  TReading = (HighByte << 8) + LowByte;
  sign = TReading & 0x8000;  // test most sig bit
  if (sign) // negative
  {
    TReading = (TReading ^ 0xffff) + 1; // 2's comp
  }
  Tc_100 = (6 * TReading) + TReading / 4;    // multiply by (100 * 0.0625) or 6.25

  whole = Tc_100 / 100;  // separate off the whole and fractional portions
  fract = Tc_100 % 100;

	if(sign) temp[0]='-';
	else 		 temp[0]='+';

	temp[1]= (whole-(whole/100)*100)/10 +'0' ;
	temp[2]= whole-(whole/10)*10 +'0';

	temp[3]='.';
	temp[4]=fract/10 +'0';
	temp[5]=fract-(fract/10)*10 +'0';

	temp[6] = '\0';
}

 
As you can see this example involves alot of lowlevel configuration specific lines which could be hidden away in the library for clarity’s sake.

The second code example is one from the standard ethernet library included with any recent installation of the arduino environment. This is code that runs straight on a WIZ5100 powered ethernet shield.
 

/*
 * Web Server
 *
 * A simple web server that shows the value of the analog input pins.
 */

#include <Ethernet.h>

byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
byte ip[] = { 10, 0, 0, 177 };

Server server(80);

void setup()
{
  Ethernet.begin(mac, ip);
  server.begin();
}

void loop()
{
  Client client = server.available();
  if (client) {
    // an http request ends with a blank line
    boolean current_line_is_blank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        // if we've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so we can send a reply
        if (c == '\n' && current_line_is_blank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println();

          // output the value of each analog input pin
          for (int i = 0; i < 6; i++) {
            client.print("analog input ");
            client.print(i);
            client.print(" is ");
            client.print(analogRead(i));
            client.println("<br />");
          }
          break;
        }
        if (c == '\n') {
          // we're starting a new line
          current_line_is_blank = true;
        } else if (c != '\r') {
          // we've gotten a character on the current line
          current_line_is_blank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);
    client.stop();
  }
}

 
Needless to say the latter is easier for the eye ( of mind ). Right now I use the WIZ5100 based shield for quick prototyping of new ideas and the ENC28j60 shield is used for more permanent setups, as the code isn’t stuff I want to rewrite on a daily basis.

Next up will be some more things I picked up :

• an rf-transmitter-receiver pair

• a PIR-sensor

• an Arduino sensor-shield

Back to homepage